チャートから分足を保存（複数銘柄対応）

UWSCのスクリプトで、チャート上の右クリックで表示される「CSV形式でデータ出力」を行います。
銘柄2.txtに記入したカテゴリ名,銘柄コードのCSVをカテゴリ毎のフォルダに順次保存します。
銘柄.txtに記入した銘柄コードのCSVを順次保存します。
ジョイ・エクスプレス（野村証券）、ネットストック・ハイスピード（松井証券）のログインも実行します。

準備

銘柄2.txt（ファイル名は指定出来ます）あるいは銘柄.txtには、一行ずつ記入します。
chart2.uwsと銘柄2.txt,銘柄.txtとは同じフォルダに入れておきます。
パスワードを設定します。
ネットストック・ハイスピード（松井証券）を利用するなら、証券会社をFALSEにします。
データを保存するフォルダパスを、folderPathに設定します。
「CSV形式でデータ出力」の上でクリックされない場合は、x,yを調節して下さい。
日付+銘柄コードのファイル名か、銘柄コードのファイル名(ファイル名日付利用=FALSE にする)で保存されます。

チャート表示を設定

ジョイ・エクスプレス、ネットストック・ハイスピードを起動した時に、上記画像のように株式チャートの画面が出てくるように設定しておきます。チャート画面は単独のウインドウで表示されるように、MDI画面（メインウインドウ内に子ウインドウが開く）ではなくてSDI画面（ドキュメント毎にウインドウが開く）にしておきます。

CSVファイルを開くプログラムを変更

拡張子CSVのファイルは、Excelでは無くて、例えばメモ帳などのテキストエディタで常に開く設定にしておきます。

スクリプト

chart2.uwsとして、保存して下さい。

// チャートからCSVを保存するユーティリティ（複数銘柄対応）
// http://www.moderns.co.jp/trade/
// 2011-05-08


カテゴリ利用 = FALSE	//カテゴリ利用のfileNameを利用するならTRUE。銘柄.txtならFALSE
fileName = "銘柄2.txt"	//カテゴリ利用の銘柄リストのファイル名

password = "*****"	// 野村用　ログインパスワードを設定して下さい。
maID = "*****"	// 松井用　ログインIDを設定して下さい。
maPass = "*****"	// 松井用　ログインパスワードを設定して下さい。

証券会社 = TRUE	//野村ジョイ・エクスプレスにログインするならTRUE。ネットストック・ハイスピード（松井証券）を利用するなら、FALSE。
folderPath = "C:\"	//データを保存するフォルダパス。このフォルダ以下に、[日付 + Data]のフォルダが作成される。

//ジョイ・エクスプレスのプログラムパス
appPath = "C:\Program Files\joyExpress\Module\JoinvestExpress.exe"

//チャート画面上で右クリック後カーソル移動幅。調節して下さい。
x = 69
y = 260		//フォントがMS Pゴシックなら、220

//windowTitle = "指数先物OPチャート"
windowTitle = "株式チャート"	//株式のチャートの場合

IFB 証券会社 THEN
	appTitle = "ジョイ・エクスプレス"
	野村ログイン(appPath,password)
ELSE
	appTitle = "ネットストック・ハイスピード"
	松井ログイン(maID,maPass)
ENDIF

GETTIME(0)

//CSVを保存するフォルダ 
folderPath = folderPath + G_TIME_YY4 + G_TIME_MM2 + G_TIME_DD2 + " Data\"
ファイル名日付利用 = FALSE	// ファイル名に日付を付けるならTRUE



dateFileName = ""
//ファイル名の日付部分を設定する。
IFB ファイル名日付利用 THEN
	dateFileName = G_TIME_YY4 + G_TIME_MM2 + G_TIME_DD2 + " "	//例 20110508
ENDIF

//チャート画面が開くまで待機。
WHILE GETID( windowTitle ) < 0
	SLEEP(1)
WEND
SLEEP(10)		//長すぎるなら適宜修正

wNum = GETID(windowTitle)

DIM FSO = CreateOLEObj("Scripting.FileSystemObject")

//folderPathのフォルダが無ければ作成する。
IFB FSO.FolderExists(folderPath) = FALSE THEN
	FSO.CreateFolder (folderPath)
ENDIF

IFB カテゴリ利用 THEN
	fid = FOPEN(fileName, F_READ)
ELSE
	fid = FOPEN("銘柄.txt", F_READ)
ENDIF


FOR 行 = 1 TO FGET(fid, -1)		//　行数分を繰り返す

	IFB カテゴリ利用 THEN
		
		カテゴリ = FGET(fid, 行, 1)
		code銘柄 = FGET(fid, 行, 2)	//　行の2つめの列のデータを取り出す
		IFB FSO.FolderExists(folderPath + カテゴリ) = FALSE THEN
			FSO.CreateFolder (folderPath + カテゴリ)
		ENDIF
		
	ELSE
		code銘柄 = FGET(fid, 行)	//　行のデータを取り出す
	ENDIF

	//PRINT code銘柄
	FileName = dateFileName + code銘柄

	//ウインドウの座標・大きさを取得
	xx = STATUS( wNum, ST_X )
	yy = STATUS( wNum, ST_Y )
	width = STATUS( wNum, ST_CLWIDTH )
	height =  STATUS( wNum, ST_CLHEIGHT )

	SLEEP(2)

	//銘柄のCode入力処理開始。
	w_ID = GetID(windowTitle)
	o_HND = GetCtlHND(w_ID, "ComboBox")
	o_ID = HNDtoID(o_HND)
	CTRLWIN(w_ID, ACTIVATE)
	SENDSTR(o_ID, code銘柄, 1, True)	
	KBD(VK_RETURN)
	//銘柄のCode入力処理終了

	wNum = GETID( windowTitle )
	CTRLWIN( wNum, ACTIVATE)

	//CSVを保存
	BTN(RIGHT, CLICK, xx+200, yy+height/3, 300)	//右クリック
	BTN(LEFT, CLICK, xx+200+x, yy+height/3+y, 300)	//「CSV形式でデータ出力」の文字列の上をクリック

	//「出力」ダイアログが開くまで待機。
	WHILE GETID("出力") < 0
		SLEEP(0.5)
	WEND
	SLEEP(0.5)
	wNum2 = GETID("出力")

	IFB カテゴリ利用 THEN
		SENDSTR(wNum2, folderPath + カテゴリ + "\"+ FileName)
	ELSE
		SENDSTR(wNum2, folderPath + FileName)
	ENDIF


	KBD(VK_RETURN, DOWN, 40)
	SLEEP(0.5)

	CTRLWIN(wNum, ACTIVATE)

NEXT
FCLOSE( fid )


EXIT //アプリケーションを閉じるなら、この行を削除

// アプリケーションを閉じる
CTRLWIN(GETID(appTitle), CLOSE2 )
SLEEP(2)
CLKITEM(GETID(appTitle,"#32770"), "はい", clk_acc or clk_short, true, 1)


Procedure 松井ログイン(maID,maPass)

	IE = CREATEOLEOBJ("InternetExplorer.Application")
	IE.visible = True
	IE.navigate("https://www.deal.matsui.co.jp/ITS/login/MemberLogin.jsp")
	BusyWait(IE)

	IESETDATA(IE,maID,"clientCD")
	IESETDATA(IE,maPass,"passwd")
	IESETDATA(IE,True,"","alt=ログイン")
	BusyWait(IE)

	IELINK(IE,"ネットストック・ハイスピード")
	BusyWait(IE)
	IE.Document.Frames("CT").Document.all.item("kidouButton").click

Fend

Procedure 野村ログイン(appPath,password)
	Exec(appPath)		//アプリを起動。

	WHILE GETID("ログイン","#32770") < 0
		SLEEP(1)
	WEND
	CTRLWIN( GETID("ログイン","#32770"), ACTIVATE)

	IDnum = GETID("ログイン","#32770")
	SENDSTR(IDnum, password , 2, true)	//パスワード入力
	KBD(VK_RETURN, CLICK, 40)

Fend

Procedure BusyWait(ie)
	repeat
	Sleep(0.2)
	until (! ie.busy) and (ie.readyState=4)
Fend

銘柄.txt

銘柄.txtとして、保存して下さい。

9501
9502
9503

銘柄2.txt

通常は、銘柄2.txtとして、保存して下さい。ファイル名はスクリプト内で指定できます。
カテゴリ名,銘柄のコード　の順に記載します。
ここでは、「電力」「225」カテゴリの2つを記載してあります。

トラブルシューティング

ジョインベスト・エクスプレスからジョイ・エクスプレスに自動的にアップデートされた場合、ファイルのパスは変わらないようです。
従って、スクリプトを次のように変更して下さい。
```
appPath = "C:\Program Files\joinvestExpress\Module\JoinvestExpress.exe"
```
Windows VISTA,7の場合、「ユーザーアカウント制御の設定」を「通知しない」にする必要があるかもしれません。

使用規約

このソフトウェアを使用したことによる一切の損害について作者は責任を負いません。

履歴

2011-05-08: ネットストック・ハイスピード（松井証券）のログインに対応。CSVファイルをExcelで開かない前提に変更した。
2010-11-07: 銘柄2.txtを利用し、カテゴリ名のフォルダ毎にCSVを保存できるようにした。銘柄のCode入力処理を変更。CSVにデータが無くファイルが開かれない場合に対処。
2010-08-12: スクリプトを改良。
2009-11-26: 「ジョインベスト・エクスプレス」から「ジョイ・エクスプレス」に変更。
2008-08-25: 掲載

ソフトウェア

ユーザログイン