楽天マーケットスピードとRSSとの自動起動

ここでは、マーケットスピードとRSSとをできるだけ確実に自動で起動させる方法を記します。
自動売買を行うには、この2つが必要になることが多いですが、これらの自動起動を確実に行おうと思ったら意外と難しいのです。

2009-8-5 mss(Market Speed Shortcut)を利用しない方法に変更。「RSS 接続中」の確認処理を内部化しました。
2009-8-9 メール送信 方法2を追加。

RSS

マーケットスピード

ログイン方法

マーケットスピードの設定

起動とログイン　（ファイル名：MSSstart.UWS）

//　設定
MSNAME = "Market Speed Ver8.0"	//　マーケットスピードの名前を設定する。
PassWord = "*****"	//ログイン用パスワードを設定
MSFolderPath = "C:\Program Files\MarketSpeed\MarketSpeed" //MarketSpeed.exeのあるフォルダを設定

//　変数を設定
PUBLIC エラーチェック
エラーチェック = 0	// MSSstart.UWSでは使用しない。

//　Market Speedが起動していたら一端終了させる。
IFB GETID(MSNAME) >= 0 THEN
	CTRLWIN(GETID(MSNAME, "MDIFrame"), CLOSE)
	SLEEP(5)
ENDIF

//　Market Speedを起動する。
EXEC(MSFolderPath + "\MarketSpeed.exe")

//　Market Speedが起動するまでSleepする。
現在時刻秒 = GETTIME(0)
WHILE (GETID(MSNAME) < 0 ) AND (GETTIME(0) < 現在時刻秒 + 60)	//60秒間で中断
	SLEEP(1)
WEND
SLEEP(5)

//　ログインする。
CTRLWIN(GETID(MSNAME, "MDIFrame"), ACTIVATE)
SLEEP(1)
SCKEY(GETID(MSNAME, "MDIFrame"), VK_ALT, VK_F10)	//　「総合サマリー」画面に設定したショーカットキーを送る。
SCKEY(GETID(MSNAME, "MDIFrame"), VK_RETURN)
SLEEP(5)
LoginWindow = GETID("Market Speed - ﾛｸﾞｲﾝ")
SENDSTR(LoginWindow, PassWord)
SLEEP(1)
SCKEY(LoginWindow, VK_RETURN)

//　ログインに失敗した場合に備えたログイン処理。（ログインが出来ないのは、サーバが混んでいる時か？）
//　Market Speed - ﾛｸﾞｲﾝの表示は出ており、パスワード入力が出来なかった状態を想定する。
//　未読の重要なお知らせのウインドウを閉じる処理。
現在時刻秒 = GETTIME(0)
WHILE (GETID("Market Speed - ﾛｸﾞｲﾝ") > 0) AND (GETTIME(0) < 現在時刻秒 + 60)	//60秒間で中断
	id = GETID("Market Speed", "#32770")
	wks = GETSTR(id, 2, STR_STATIC)
	IF POS("ネットワークに接続できません", wks) > 0 THEN CLKITEM(id, "OK", CLK_BTN)
	IF POS("「未読の重要なお知らせ」があります。", wks) > 0 THEN CLKITEM(id, "OK", CLK_BTN)
	IF POS("お知らせがあります。", wks) > 0 THEN CLKITEM(id, "OK", CLK_BTN)

	ID2 = GETID("Market Speed - ﾛｸﾞｲﾝ")
	IFB ID2 >= 0 THEN
		SENDSTR(ID2, PassWord , 2)
		CLKITEM(ID2, "OK", CLK_BTN)
		SLEEP(2)
	ENDIF
WEND

//　RSSを起動する。
EXEC(MSFolderPath + "\RSS.exe")

CALL MSScheck.UWS	//　RSSの接続を確認するなら呼び出す。

---

昼にRSSが一端途切れるのを回避する方法

昼のRSS切断対策

---

ログアウト→ログイン（ファイル名：MSSreStart.UWS）

MSNAME = "Market Speed Ver8.0"	//　マーケットスピードの名前を設定する。
PassWord = "*****"	//ログイン用パスワードを設定

//　変数を設定
PUBLIC エラーチェック
エラーチェック = 0

//　ログアウトをし再ログインする。
CTRLWIN(GETID(MSNAME, "MDIFrame"), SHOW)
CTRLWIN(GETID(MSNAME, "MDIFrame"), NORMAL)	//ウインドウが表示されていないと、ログアウト確認などダイアログのボタンのクリックがうまくいかない。
CTRLWIN(GETID(MSNAME, "MDIFrame"), ACTIVATE)
SLEEP(1)
	
ID = GETID("Market Speed", "#32770")
IFB POS("サーバとの接続が切断されました。再ログインが必要です。", GETSTR(ID, 2, 1)) > 0 THEN
	// 例えばプロバイダとの接続を切断して再接続した場合、
	// Market Speedには「サーバとの接続が切断されました。再ログインが必要です。」のダイアログが表示され、
	// OKボタンを押すとログアウトした状態になる。（ルータ再起動で確認）
	CLKITEM(ID, "はい", clk_acc OR CLK_SHORT, TRUE, 1)	// 「はい」「OK」の2種類のダイアログがあるため、それら2つに対応。
	CLKITEM(ID, "OK", clk_acc OR CLK_SHORT, TRUE, 1)
ELSE
	// ログアウトを行う処理。
	// ログアウトボタンをクリックする。
	// 仮に「サーバとの接続が切断されました。再ログインが必要です。」のダイアログが表示されたままの状態で、
	// この処理を行うと、「ログアウトしますか？」のダイアログは表示される。「はい」ボタンも押すことはできる。

	//ウインドウのサイズを取得し、右上からログアウトボタンのある位置をクリックする。
	wNum = GETID(MSNAME, "MDIFrame")
	CTRLWIN( wNum, ACTIVATE)

	xx = STATUS( wNum, ST_X )
	yy = STATUS( wNum, ST_Y )
	width = STATUS( wNum, ST_CLWIDTH )
	// height =  STATUS( wNum, ST_CLHEIGHT )
	BTN(LEFT, CLICK, xx + width - 30, yy + 45, 300)	//「ログアウト」のボタンをクリック。 - 30, + 45はウインドウの右上からの補正した位置。適宜調節が必要。VISTAは + 45, XPのクラシック表示は + 30あたり。
	SLEEP(1)
	
	現在時刻秒 = GETTIME(0)
	WHILE (GETID("ログアウト確認", "#32770") < 0 ) AND (GETTIME(0) < 現在時刻秒 + 60)
		SLEEP(1)
	WEND
	SLEEP(2)

	// この時点で「サーバとの接続が切断されました。再ログインが必要です。」が出る可能性はある。
	// この場合、「ログアウトしますか？」の「はい」ボタンは押せる。（ルータ再起動で確認）

	id = GETID("ログアウト確認", "#32770")
	wks = GETSTR(id, 2, STR_STATIC)
	IFB POS("ログアウトしますか？", wks) > 0 THEN
	CLKITEM(id, "はい", CLK_BTN)
	ELSE
		エラーチェック = 1
	ENDIF
	SLEEP(3)

	// この時点で「サーバとの接続が切断されました。再ログインが必要です。」のダイアログは出る可能性がある。
	// ただし、この場合、「ログアウトしますか？」で「はい」を押しても、「ログアウトします。」のダイアログが出ない。
	// （再ログインが必要です。で、OKボタンを押したら、OFFLINEになるからか？）
	
	現在時刻秒　= GETTIME(0)
	WHILE (GETID("Market Speed", "#32770") < 0 ) AND (GETTIME(0) < 現在時刻秒 + 60)
		SLEEP(1)
	WEND
	SLEEP(3)	//　ログアウトしますのOKボタンが押されない場合があるので、ここにSleepを入れてうまくいくかどうかテストする。

	// 「ログアウトします。」のダイアログが表示されているこの時点で
	// 「サーバとの接続が切断されました。再ログインが必要です。」のダイアログは出ないようだ。
	// 「ログアウトします。」で、「はい」を押してOFFLINEになる。

	エラーチェックB = 0
	現在時刻秒 = GETTIME(0)
	WHILE (GETID("Market Speed", "#32770") > 0) AND (GETTIME(0) < 現在時刻秒 + 60)	//60秒間で中断
		id = GETID("Market Speed", "#32770")
		wks = GETSTR(id, 2, STR_STATIC)
		IFB POS("サーバとの接続が切断されました。再ログインが必要です。", wks ) > 0 THEN
			CLKITEM(id, "はい", clk_acc OR CLK_SHORT, TRUE, 1)
			CLKITEM(id, "OK", clk_acc OR CLK_SHORT, TRUE, 1)
			エラーチェックB = 1
			SLEEP(2)
			// OKボタンを押したら、自動的にOFFLINEの状態になる。従って、ログアウトしますダイアログが表示される必要はないようだ。
			// PRINT "「再ログインが必要です」ダイアログが、ログアウト確認以後に表示されました。"
		ENDIF
		IFB POS("ログアウトします。", wks) > 0 THEN
			CLKITEM(id, "はい", clk_acc OR CLK_SHORT, TRUE, 1)	// 「はい」「OK」の2種類のダイアログがあるため、それら2つに対応。
			CLKITEM(id, "OK", CLK_BTN)
			エラーチェックB = 2
			SLEEP(2)
		ENDIF
	WEND
	IF エラーチェックB = 0 THEN エラーチェック = 2
ENDIF

SLEEP(2)

//　ログインする。
CTRLWIN(GETID(MSNAME, "MDIFrame"), ACTIVATE)
SLEEP(1)
SCKEY(GETID(MSNAME, "MDIFrame"), VK_ALT, VK_F10)	//　「総合サマリー」画面に設定したショーカットキーを送る。
SCKEY(GETID(MSNAME, "MDIFrame"), VK_RETURN)
SLEEP(5)
LoginWindow = GETID("Market Speed - ﾛｸﾞｲﾝ")
SENDSTR(LoginWindow, PassWord)
SLEEP(1)
SCKEY(LoginWindow, VK_RETURN)

//　ログインに失敗した場合に備えたログイン処理。（ログインが出来ないのは、サーバが混んでいる時か？）
//　Market Speed - ﾛｸﾞｲﾝの表示は出ており、パスワード入力が出来なかった状態を想定する。
//　未読の重要なお知らせのウインドウを閉じる処理。
現在時刻秒 = GETTIME(0)
WHILE (GETID("Market Speed - ﾛｸﾞｲﾝ") > 0) AND (GETTIME(0) < 現在時刻秒 + 60)	//60秒間で中断
	id = GETID("Market Speed", "#32770")
	wks = GETSTR(id, 2, STR_STATIC)
	IF POS("ネットワークに接続できません", wks) > 0 THEN CLKITEM(id, "OK", CLK_BTN)
	IF POS("「未読の重要なお知らせ」があります。", wks) > 0 THEN CLKITEM(id, "OK", CLK_BTN)
	IF POS("お知らせがあります。", wks) > 0 THEN CLKITEM(id, "OK", CLK_BTN)

	ID2 = GETID("Market Speed - ﾛｸﾞｲﾝ")
	IFB ID2 >= 0 THEN
		SENDSTR(ID2, PassWord , 2)
		CLKITEM(ID2, "OK", CLK_BTN)
		SLEEP(2)
	ENDIF
WEND

// MSScheck.UWSが処理中の間に再びログイン処理を行うと、
// タスクトレイのアイコンが、「接続処理中」の場合に重なり（と思われる）エラーメールが送信される場合がある。
CALL MSScheck.UWS	//　RSSの接続を確認するなら呼び出す。

---

RSSが接続したかをチェックする（ファイル名：MSScheck.UWS）

コンピュータ名 = DOSCMD("echo　%computername%")	//http://www.nagomi-jp.net/~liners/p01.htm

//　タスクトレイのチェック
DIM Check = FALSE
FOR i = 0 TO GETITEM(GETID("", "Shell_TrayWnd"), ITM_TOOLBAR) - 1
	//PRINT ALL_ITEM_LIST[i]
	IF ALL_ITEM_LIST[i] = "RSS  接続中" THEN Check = TRUE
NEXT

GETTIME(0)

IFB Check = TRUE AND エラーチェック = 0 THEN
	件名   = コンピュータ名 + "定時確認"
	文書   = コンピュータ名 + "マーケットスピードを起動/再ログインしました<#CR>" + G_TIME_HH2 + "時" + G_TIME_NN2 + "分" + G_TIME_SS2 + "秒"
ELSE
	件名   = コンピュータ名 + "MSS Error"
	文書   = コンピュータ名 + "エラーチェックNo." + エラーチェック + "<#CR>マーケットスピードにログインできませんでした。<#CR>" + G_TIME_HH2 + "時" + G_TIME_NN2 + "分" + G_TIME_SS2 + "秒"
ENDIF

//　メール送信
CALL mail.uws
送信元 = "HOGE@FUGA.or.jp"
送信先 = "FUGE@HOGA.or.jp"
sendMail(送信元, 送信先, 件名, 文書)	// mailfrom,mailto,subject,body

EXIT

タスクトレイにあるアイコンのポップアップ文字列の取得

処理結果をメールで送信　方法1

処理結果をメールで送信　方法2

// basp21.dll を利用して、メールを送信
bobj = CreateOLEObj("basp21")

svname = "mail.example.com"	//通常、SMTPサーバ名
mailfrom = "HOGE@FUGA.or.jp"	//送信元
mailto = "FUGE@HOGA.or.jp"	//送信先
files = ""

output = bobj.SendMail(svname,mailto,mailfrom, 件名,文書,files)

---

まとめ

メモ

以前の解説